// Oral Diazepam pbpk simulation ver 1.3 -- 02/26/08  D Neubauer
//
// oral route: mouth -> stomach -> small intestine ->  gastrointestinaltract  &  colon
//
//
//

Pbpk2CppVersion: 1.3;             // expected version number

Global {
constant: totalVolume = 70000.0 ;           // ml
string: volumeUnits = ml ;                  // all volumes in ml
string: timeUnits =  sec. ;                 // all times in seconds
constant: totalFlow =  (6000.0 / 60.0) ;    // 6000.0 ml/min
constant: startTime = 0 ;                   // seconds
constant: stopTime = (13 * 3600) ;          //  (72 hours or 13)
constant: dTime = 1.0 ;                     // timeStep, seconds
numericalIntegration: eulers ;           // eulers or rungekutta4
}


Substance {
name: diazepam ;
string: units = ng ;
constant: blood2PlasmaRatio = 0.57 ;                 // 0.57 to convert CbloodTotal to Cplasma
constant: siinternalTransitRate = (41.9e-5) ;    // tsi=199min (40min-360min) kt=#comp/tsi = 5/(199*60)
constant: siabsorptionRate = (49.7e-5) ;         // ka=kt(1/(1-F)^(1/#comp) -1), F=about 100%
}

  
Compartment {
name: lungs ;
constant: volume = 0.0077 * global.totalVolume ;                 // fraction of total
[                    
substance: diazepam ;
constant: partitionCoefficientBlood = 0.59;
constant: rateConstant = (global.totalFlow) / (volume * partitionCoefficientBlood) ;
massBalance:  -(rateConstant * amount)  + (venousBlood.rateConstant * venousBlood.amount)  ;
]
}
  
Compartment {      
name: brain ;
constant: volume = 0.02 * global.totalVolume  ;                   // fraction of total
constant: bloodFlow  =  0.120 ;                    // fraction of CO
[                    
substance: diazepam ;
constant: partitionCoefficientBlood = 0.35;
constant: rateConstant = (bloodFlow *  global.totalFlow) / (volume * partitionCoefficientBlood) ;
massBalance: -(rateConstant * amount)  + (bloodFlow * arterialBlood.rateConstant * arterialBlood.amount)  ;
]
}
                   
Compartment {      
name: heart ;      
constant: volume = 0.0047 * global.totalVolume  ;                   // fraction of total
constant: bloodFlow = 0.04 ;                    // fraction of CO
[                    
substance: diazepam ;
constant: partitionCoefficientBlood = 0.9;
constant: rateConstant = (bloodFlow *  global.totalFlow) / (volume * partitionCoefficientBlood) ;
massBalance: -(rateConstant * amount)  + (bloodFlow * arterialBlood.rateConstant * arterialBlood.amount)  ;
]
}
                                                         
Compartment {      
name: liver ;
constant: volume = 0.0257 * global.totalVolume  ;                   // fraction of total
constant: bloodFlow = 0.060 ;                    // fraction of CO
constant: bloodFlowOutput = 0.25 ;               // special case: hepatic artery + gastrointestinal tract
[                    
substance: diazepam ;
constant: partitionCoefficientBlood = 0.84;
constant: clearanceBlood = 0.9747 ;       // CLplasma = 28 ml/min; CLblood(actually CLtissue) = CLPlasma/(BloodToPlasmaRatio*Kp) = 28/(.57*.84) = 58.48ml/min = .9747 ml/sec 
constant: rateConstant =  (bloodFlowOutput * global.totalFlow) / (volume * partitionCoefficientBlood) ;
constant: excretionRatio = clearanceBlood / volume ; 
massBalance: -(rateConstant * amount)  - (excretionRatio * amount)  + (bloodFlow * arterialBlood.rateConstant * arterialBlood.amount)  + (gastrointestinalTract.rateConstant * gastrointestinalTract.amount)  ;
]
[                    
substance: diazepamExcreted ;
massBalance: (diazepam.excretionRatio * diazepam.amount) ;
]
}
                   
Compartment {      
name: kidneys ; 
constant: volume = 0.0044 * global.totalVolume  ;                   // fraction of total
constant: bloodFlow = 0.19 ;                    // fraction of CO
[                    
substance: diazepam ;
constant: partitionCoefficientBlood = 0.7;
constant: rateConstant = (bloodFlow *  global.totalFlow) / (volume * partitionCoefficientBlood) ;
massBalance: -(rateConstant * amount)  + (bloodFlow * arterialBlood.rateConstant * arterialBlood.amount)  ;
]
}


Compartment {      
name: stomach ; 
[                    
substance: diazepam ;
constant: gastricEmptyingRateConstant = (167e-5) ;   // tge= 30min (10-60min) kge=1/tge = 1/(30*60)  = 56e-5, 20min= 84e-5, 10min=167e-5
massBalance: -(gastricEmptyingRateConstant * amount) ; 
]
}


Compartment {      
name: smallIntestine1 ; 
[                    
substance: diazepam ;
constant: internalTransitRateConstant = (siinternalTransitRate) ;
constant: absorptionRateConstant      = (siabsorptionRate     ) ;     
massBalance: -(internalTransitRateConstant * amount) - (absorptionRateConstant * amount) + (stomach.gastricEmptyingRateConstant * stomach.amount) ; 
]
}


Compartment {      
name: smallIntestine2 ; 
[                    
substance: diazepam ;
constant: internalTransitRateConstant = (siinternalTransitRate) ;
constant: absorptionRateConstant      = (siabsorptionRate     ) ;     
massBalance: -(internalTransitRateConstant * amount) - (absorptionRateConstant * amount) + (smallIntestine1.internalTransitRateConstant * smallIntestine1.amount) ; 
]
}


Compartment {      
name: smallIntestine3 ; 
[                    
substance: diazepam ;
constant: internalTransitRateConstant = (siinternalTransitRate) ;
constant: absorptionRateConstant      = (siabsorptionRate     ) ;     
massBalance: -(internalTransitRateConstant * amount) - (absorptionRateConstant * amount) + (smallIntestine2.internalTransitRateConstant * smallIntestine2.amount) ; 
]
}


Compartment {      
name: smallIntestine4 ; 
[                    
substance: diazepam ;
constant: internalTransitRateConstant = (siinternalTransitRate) ;
constant: absorptionRateConstant      = (siabsorptionRate     ) ;     
massBalance: -(internalTransitRateConstant * amount) - (absorptionRateConstant * amount) + (smallIntestine3.internalTransitRateConstant * smallIntestine3.amount) ; 
]
}


Compartment {      
name: smallIntestine5 ; 
[                    
substance: diazepam ;
constant: internalTransitRateConstant = (siinternalTransitRate) ;
constant: absorptionRateConstant      = (siabsorptionRate     ) ;     
massBalance: -(internalTransitRateConstant * amount) - (absorptionRateConstant * amount) + (smallIntestine4.internalTransitRateConstant * smallIntestine4.amount) ; 
]
}


Compartment {      
name: colon ; 
[                    
substance: diazepam ;       // repository
massBalance: (smallIntestine5.internalTransitRateConstant * smallIntestine5.amount) ; 
]
}

                   
Compartment {      
name: gastrointestinalTract ; 
constant: volume = 0.0214 * global.totalVolume  ;                   // fraction of total
constant: bloodFlow = 0.190 ;                    // fraction of CO
[                    
substance: diazepam ;
constant: partitionCoefficientBlood = 0.69;
constant: rateConstant = (bloodFlow *  global.totalFlow) / (volume * partitionCoefficientBlood) ;
massBalance: -(rateConstant * amount)  + (smallIntestine1.absorptionRateConstant * smallIntestine1.amount)  + (smallIntestine2.absorptionRateConstant * smallIntestine2.amount)  + (smallIntestine3.absorptionRateConstant * smallIntestine3.amount)  + (smallIntestine4.absorptionRateConstant * smallIntestine4.amount)  + (smallIntestine5.absorptionRateConstant * smallIntestine5.amount)  + (bloodFlow * arterialBlood.rateConstant * arterialBlood.amount)  ;
]
}

                   
Compartment {      
name: muscle ;              
constant: volume = 0.4143 * global.totalVolume  ;                   // .4143 fraction of total
constant: bloodFlow = 0.17  ;                    // fraction of CO
[                    
substance: diazepam ;
constant: partitionCoefficientBlood = 0.38;
constant: rateConstant = (bloodFlow *  global.totalFlow) / (volume * partitionCoefficientBlood) ;
massBalance: -(rateConstant * amount)  + (bloodFlow * arterialBlood.rateConstant * arterialBlood.amount)  ;
]
}
                   
Compartment {      
name: skin ;
constant: volume = 0.0371 * global.totalVolume  ;                   // fraction of total
constant: bloodFlow = 0.05 ;                    // fraction of CO
[                    
substance: diazepam ;
constant: partitionCoefficientBlood = 0.80;
constant: rateConstant = (bloodFlow *  global.totalFlow) / (volume * partitionCoefficientBlood) ;
massBalance: -(rateConstant * amount)  + (bloodFlow * arterialBlood.rateConstant * arterialBlood.amount)  ;
]
}

Compartment {      
name: adiposeTissue ;
constant: volume = 0.25 * global.totalVolume  ;                   // .25 fraction of total
constant: bloodFlow = 0.10 ;                    // fraction of CO
[                    
substance: diazepam ;
constant: partitionCoefficientBlood = 4.4;
constant: rateConstant = (bloodFlow *  global.totalFlow) / (volume * partitionCoefficientBlood) ;
massBalance: -(rateConstant * amount)  + (bloodFlow * arterialBlood.rateConstant * arterialBlood.amount)  ;
]
}
                   
Compartment {      
name: rest ;
constant: volume = 0.1347 * global.totalVolume  ;                   // fraction of total
constant: bloodFlow = 0.08 ;                    // fraction of CO
[                    
substance: diazepam ;
constant: partitionCoefficientBlood = 0.07;  
constant: rateConstant = (bloodFlow *  global.totalFlow) / (volume * partitionCoefficientBlood) ;
massBalance: -(rateConstant * amount)  + (bloodFlow * arterialBlood.rateConstant * arterialBlood.amount)  ;
]
}

                   
Compartment {      
name: arterialBlood ;
constant: volume = 0.0243 * global.totalVolume  ;                 // fraction of total
[                    
substance: diazepam ;  
constant: rateConstant = (global.totalFlow) / volume ;
massBalance: -(rateConstant * amount)  + (lungs.rateConstant * lungs.amount)  ;
]
}
                   

Compartment {      
name: venousBlood ;             
constant: volume = 0.0557 * global.totalVolume  ;                 // fraction of total
[                    
substance: diazepam ;   
constant: rateConstant = (global.totalFlow) / volume ;                                                                                                                                                                                                                                           
massBalance: -(rateConstant * amount)  + (rest.rateConstant * rest.amount)  + (adiposeTissue.rateConstant * adiposeTissue.amount)  + (skin.rateConstant * skin.amount)  + (muscle.rateConstant * muscle.amount)  + (kidneys.rateConstant * kidneys.amount)  + (liver.rateConstant * liver.amount)  + (heart.rateConstant * heart.amount)  + (brain.rateConstant * brain.amount)  ;
]
}


                   
Dosage {
[
name: initial dose of diazepam ;
substance: diazepam;
compartment: stomach ;
amount: 2.0e6 ;    // 
//amount: 10.0e6 ;    // 
startTime: 0 ;     // seconds
type: oral ;
]
}


Plotting {
plotTime: 60 ;               // 600 = 10 * 60 seconds (plot every 10 minutes)
plotTitle: PBPk of Diazepam, (Oral: 2mg) (vs Friedman1992, 2mg) ;
//plotTitle: PBPk of Diazepam, (Oral: 10mg) (vs Friedman1992, 10mg) ;
//plotTitle: PBPk of Diazepam, (Oral: 5mg) (vs Friedman1992, 5mg) ;
//plotTitle: PBPk of Diazepam, (Oral: 10mg) (vs Klotz1975, 10mg) ;
yAxis: Diazepam (ng/ml) ;
yMinimum: 1.0 ;
yMaximum: 100.0 ;           // 500 10mg , 300 5mg , 100 2mg
// yLog: yes;
xAxis: time (hours) ;
xScale: 3600.0 ;                    // convert seconds to hours
//experimentalFile: exp_ochs1985.dat ;
//experimentalTitle: experimental (Ochs1985);
//experimentalFile: exp_igari1983.dat ;
//experimentalTitle: experimental (Igari1983);
//experimentalFile: exp_klotz1976.dat ;
//experimentalTitle: experimental (Klotz1976);
//experimentalFile: exp_klotz1975.dat ;
//experimentalTitle: experimental (Klotz1975);
//experimentalFile: exp_klotz1975o.dat ;
//experimentalTitle: experimental (Klotz1975 Oral);
experimentalFile: exp_friedman1992o2mg.dat ;
experimentalTitle: experimental (Friedman1992 2mg Oral);
//experimentalFile: exp_friedman1992o5mg.dat ;
//experimentalTitle: experimental (Friedman1992 5mg Oral);
//experimentalFile: exp_friedman1992o10mg.dat ;
//experimentalTitle: experimental (Friedman1992 10mg Oral);
substanceBlood: venousBlood.diazepam ;    // convert CbloodTotal to Cplasma
substance: adiposeTissue.diazepam ;
substance: kidneys.diazepam ;
substance: brain.diazepam ;
printout: diazepamTotal = stomach.diazepam + colon.diazepam + smallIntestine1.diazepam  + smallIntestine2.diazepam  + smallIntestine3.diazepam  + smallIntestine4.diazepam  + smallIntestine5.diazepam + lungs.diazepam  + brain.diazepam + heart.diazepam + liver.diazepam + liver.diazepamExcreted + kidneys.diazepam + gastrointestinalTract.diazepam + muscle.diazepam + skin.diazepam + adiposeTissue.diazepam + rest.diazepam + arterialBlood.diazepam + venousBlood.diazepam ;
}


//PrintReport {                 
//printout: totalVolume = lungs.volume  + brain.volume + heart.volume + liver.volume + kidneys.volume + gastrointestinalTract.volume + muscle.volume + skin.volume + adiposeTissue.volume + rest.volume + arterialBlood.volume + venousBlood.volume ;
//printout: totalFlow = brain.bloodFlow + heart.bloodFlow + liver.bloodFlow + kidneys.bloodFlow + gastrointestinalTract.bloodFlow + muscle.bloodFlow + skin.bloodFlow + adiposeTissue.bloodFlow + rest.bloodFlow ;
//}